Kultúra 6. FKERES, MAX, INDEX, HOL.VAN

Egy város vezetése meghirdette a kultúra hónapját. Ebben az időszakban a diákok kedvezményesen látogathatták a színházat és mozit. Az iskolában két osztály diákjait megkérték, hogy jegyezzék fel a hónap során a színház- és mozilátogatásaik számát, és vezessenek pontos feljegyzéseket könyv- és újságolvasásukról.

6. A B56-os cellába függvény segítségével határozza meg, hogy ki olvasott a legtöbbet a két osztályból!

Bontsuk fel a feladatot. A MAX függvénnyel keressük meg hány lapot olvasott a legtöbbet olvasott diák.

Ehhez a MAX függvényt hívjuk segítségül.

MAX : Egy értékhalmazban szereplő legnagyobb számot adja meg. A logikai értékeket és szövegeket figyelmen kívül hagyja.

Képlete:

 =MAX(szám1;szám2;....szám255)

szám1;szám2;....szám255  -  az olvasott oldalak száma F2:F43

Képlete:

=MAX(F2:F43)

Eredmény : 2023 lesz.

Keressük meg a hozzá tartozó diákot FKERES függvénnyel.

FKERES -  Egy táblázat bal szélső oszlopában megkeres egy értéket, és a megtalált értékhez tartozó sorból a megadott oszlopban elhelyezkedő értéket adja eredményül; alapesetben a táblázatnak növekvő sorrendbe rendezettnek kell lennie.

A bal szélső oszlopban megkeresett értékhez viszonyít, így a diákok neveit másoljuk át a J oszlopba.

J2 cellába írjuk be =A2 képletet, majd másoljuk végig J43-ig.

Képlete:

=FKERES(keresési_érték; tábla; oszlop_szám; [tartományban_keres])

keresési_érték - az előzőleg meghatározott könyvoldal - MAX(F2:F43)

tábla : az olvasott oldalaktól a diákok nevéig, amit a J oszlopba másoltunk - F2:J43

oszlop_szám 5, mert jobbra az 5. oszlopba írattuk be a diákok neveit

[tartományban_keres] : Opcionálisan megadhatja az IGAZ értéket, ha a visszatérési érték kereséséhez közelítő egyezést szeretne előírni, vagy a HAMIS értéket, ha pontos egyezést. Ha nem ad meg semmit, az alapértelmezett érték az IGAZ, vagyis a közelítő egyezés. Nekünk pontos egyezésre van szükségünk - HAMIS.

 Képlet:

=FKERES(MAX(F2:F43);F2:J43;5;HAMIS)

Eredmény:

Másik megoldás lehet a HOL.VAN és az INDEX függvény használatával megkeresni a legtöbbet olvasott diákot.

HOL.VAN : Egy adott értéknek megfelelő tömbelem viszonylagos helyét adja meg adott sorrendben.

Képlete:

=HOL.VAN(keresési_érték; tábla; [egyezés_típusa])

keresési_érték : az előzőleg megkeresett érték : MAX(F2:F43)

 tábla :  ugyanaz a tábla, amit az előbb használtunk : F2:F43

egyezés_típusa : egyenlőnek kell lenni a keresési értékkel, tehát 0.

Képlete:

=HOL.VAN(MAX(F2:F43);F2:F43;0)

Eredmény : 5 , mert a táblázaton belül az 5. sorban helyezkedik el.

INDEX függvény segítségével írassuk ki a hozzá kapcsolódó diákot.

INDEX - Értéket vagy hivatkozást ad vissza egy adott tartomány bizonyos sorának és oszlopának metszéspontjában lévő cellából.

Képlete:

 =INDEX(tömb; sor_szám; [oszlop_szám])

 tömb : a diákok nevei - A2:A43

sor_szám : az előzőleg megkapott sorszám : HOL.VAN(MAX(F2:F43);F2:F43;0)

 [oszlop_szám] egy oszlop van, nem szükséges kiírni .

=INDEX(A2:A43;HOL.VAN(MAX(F2:F43);F2:F43;0))

 Eredmény:

Hogyan oldanád meg?

7.A B61:C62 tartományba határozza meg, hogy a két osztálynak külön-külön hány színház-, illetve mozijegyre volt szüksége!