TAJ szám

Képzésének előírt törvényi szabályai (1996. évi XX.tv):

1. 9 számjegyből álló szám

2. Az első 8 számjegy egy folyamatosan kiadott egyszerű sorszám, amely mindig az előző, utoljára kiadott sorszámból egy hozzáadásával keletkezik. A kilencedik számjegy egy ellenőrző, CDV-kód.

3. Az első 8 számjegyéből a páratlan helyen állókat hárommal, a páros helyen állókat héttel szorozzuk, és a szorzatokat összeadjuk. Az összeget tízzel elosztva a maradékot tekintjük a kilencedik, azaz a CDV-kódnak.

Ehhez a ÉRTÉK ; MARADÉK ; HA  ; KÖZÉP függvény lesz segítségünkre.

 Feladat:

Ellenőrizzünk egy TAJ számot, megfelel e a feltételeknek, lehet e valódi TAJ szám.

Megoldás:

1. Mivel a TAJ számok 0-val is kezdődhetnek, ezért szöveges formátumban tudjuk csak begépelni az excel táblánkba.

Szöveg formátum beállítása - jobb egérgomb cellaformázás:

2. A páratlan helyen állókat 3-mal, a páros helyen állókat szeretnénk 7-tel megszorozni.

Ehhez szükségünk van a kilenc számjegyre külön-külön.  

Jelen pillanatban van egy 9 számjegynek kinéző szöveges formátumú adathalmazunk.

a.

Ahhoz, hogy egyesével meg tudjuk vizsgálni a 9 karaktert, szét kell őket szedni, amit a KÖZÉP függvénnyel könnyen megtehetünk. 

A B4 cellába a következő képletet kellene beírni: 

=KÖZÉP(B1;A4;1) , ez azt jelenti, hogy a B1 cellában levő TAJ számot az A4-dik (1 - első) karaktertől kezdve írjon ki 1 db karaktert. 

Persze ezt nem szeretnénk kilencszer bepötyögni, így mikor beírjuk a B1 cellát, akkor rögtön megnyomjuk az F4 billentyűt, így most itt tartunk:

=KÖZÉP($B$1;A4;1)

b.

Szorzást és összeadást viszont csak szám formátumban tud értelmezni az EXCEL, az átalakításhoz segítséget nyújt az ÉRTÉK függvény.

A függvényeket egymásba tudjuk kapcsolni, ezért most is így teszünk.

Alakítsuk át a számnak kinéző 1 karakter hosszú szövegünket számmá.

=ÉRTÉK(KÖZÉP($B$1;A4;1)) közben figyeljünk, hogy minden zárójelnek legyen párja.

Nem szeretnénk kilencszer beírni a függvényt, így a B4 cella jobb alsó sarkára kétszer rákattintva automatikusan kitöltődik a számjegy oszlop, szétszedve egyesével a TAJ számot és számmá alakítva.

 c.

Páratlan vagy páros?

Páratlan egy szám, ha kettővel osztom, akkor a maradék 1. 

Páros egy szám, ha kettővel osztom, akkor a maradék 0.

MARADÉK függvény segítségével meg tudom határozni, hogy páros sorszámú vagy páratlan sorszámú a TAJ szám egyes tagjai.

=MARADÉK(A4;2) , az eredmény 1, tehát az A4=1 páratlan sorszám, ha páratlan, akkor viszont tudjuk, hogy 3-mal kell beszorozni, ellenkező esetben 7-tel.

Logikai vizsgálatnak kell alávetni az eredményt: 

Ha függvény segítségével, ha 1, vagyis páratlan, akkor szorozza meg a B4 cella tartalmát 3-mal, vagy E4-gyel, ha hamis, akkor 7-tel, vagy E5-tel.

 =HA(MARADÉK(A4;2)=1;B4*$E$4;B4*$E$5)

Mivel nem szeretnénk mind a 8 vizsgált számnál beírni a képletet, ezért a E4 és E5 cellák beírásánál F4 billentyűvel, vagy $ billentyű lenyomásával állandóvá teszem a két szorzót.

A C4 cella sarkára kétszer kattintva kitölti nekünk a szorzat oszlopot. Vigyázzunk, nincs szükség a 9. cella kitöltésére.

d.

Adjuk össze az első 8 számjegy szorzatát a SZUM függvény használatával.

=SZUM(C4:C11)

e. 

Az összeget tízzel elosztva a maradékot tekintjük a kilencedik, azaz a CDV-kódnak.

A maradékhoz ismét a MARADÉK függvényre lesz szükségünk, és egy HA logikai függvényre, hogy kiderüljön, hogy "Jó" vagy "Téves" a beírt TAJ szám.

Maradék megállapítása:

=MARADÉK(C13;10)  eredmény a fenti példában 5, de nem erre van szükség.

Vizsgáljuk meg igaz, vagy hamis. Ha igaz, írja ki "Jó", ha hamis, akkor "Téves".

A két függvényt össze tudjuk kapcsolni:

=HA(MARADÉK(C13;10)=B12;"Jó";"Téves") ekkor kiírja, hogy megegyezik e a 9. számjeggyel, ami a B12 cellában van.

 Változtassunk egy karaktert a TAJ számban:

 A feladatot elvégeztük, ha nem megfelelő az utolsó CDV kód, akkor kiírja, hogy "Téves", viszont ha megfelel a feltételeknek, akkor pedig, hogy "Jó".